Querydsl - Spring 3.x 세팅 [문제해결]

Spring 2.x - build.gradle

buildscript {
    ext {
        queryDslVersion = "5.0.0"
    }
}

plugins {
    id 'org.springframework.boot' version '2.7.0'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    // querydsl 추가
    id "com.ewerk.gradle.plugins.querydsl" version "1.0.10"
    id 'java'
}

group = 'study'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.h2database:h2'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    // querydsl 추가
    implementation "com.querydsl:querydsl-jpa:${queryDslVersion}"
    annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}"
}

tasks.named('test') {
    useJUnitPlatform()
}

// querydsl 추가 시작
// Q클래스를 생성하면 저장하는 위치
def querydslDir = "$buildDir/generated/querydsl"
querydsl {
    jpa = true
    querydslSourcesDir = querydslDir
}
sourceSets {
    main.java.srcDir querydslDir
}
configurations {
    querydsl.extendsFrom compileClasspath
}
compileQuerydsl {
    options.annotationProcessorPath = configurations.querydsl
}
// querydsl 추가 끝

Spring 3.x - build.gradle

Spring 3.x 부터는 id "com.ewerk.gradle.plugins.querydsl" version "1.0.10" 플러그인을 사용하지 못한다.
-> 위 플러그인을 사용하면 compileQuerdsl 이라는 Task 가 생기고 실행하면 QClass 를 정해진 위치에 생성한다.

이 플러그인을 사용하지 못하기 때문에 task에 직접 설정을 추가해야 한다.

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.3'
    id 'io.spring.dependency-management' version '1.1.4'
}

group = 'study'
version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = '17'
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.9.0'
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.h2database:h2'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'

    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

}

tasks.named('test') {
    useJUnitPlatform()
}

// 아래부터는 버전을 변경할 때 소스루트 설정으로 인해 발생할 수 있는 문제를 해결할 수 있는 코드

def querydslSrcDir = "$projectDir/build/generated"
clean {
    delete file(querydslSrcDir)
}

// 아래의 옵션은, `src/main/generated 패키지에 QClass를 직접 추가해준다.
tasks.withType(JavaCompile) {
    options.generatedSourceOutputDirectory = file(querydslSrcDir)
}

Spring 2.x -> Spring 3.x로 버전업 시 발생할 수 있는 문제

Spring 3.x의 경우 아래와 같이
generated/sources/annotationProcessor/java/main/패키지에 QClass가 생성된 것을 확인할 수 있다.

Spring 2.x의 경우 아래의 구문을 통해 루트 소스 `$Projectdir를 지정해줬지만, Spring 3.x의 경우 아래의 구문을 사용하지 못한다.

• 소스 루트 : build/generated

querydsl {
    jpa = true
    querydslSourcesDir = querydslDir
    library = "com.querydsl:querydsl-apt"
}

따라서 아래의 구문을 추가해 소스루트를 build/generated로 변경해 문제를 해결할 수 있다.

def querydslSrcDir = "$projectDir/build/generated"
clean {
    delete file(querydslSrcDir)
}

// 아래의 옵션은, `src/main/generated 패키지에 QClass를 직접 추가해준다.
tasks.withType(JavaCompile) {
    options.generatedSourceOutputDirectory = file(querydslSrcDir)
}

그 결과, 아래와 같이 소스루트가 정상적으로 변경된 것을 확인할 수 있다.