📌 워크로드 상황 정리

1. 특정 EC2 인스턴스 내 Docker로 Jenkins 컨테이너 운영
2. Jenkins Pipeline 내에서 Git Branch Checkout 정의
3. Jenkins Pipeline 내에서 AWS CLI 사용자 정의
4. Jenkins Pipeline 내에서 Dockerfile 정의
5. Jenkins Pipeline 내에서 Slack Notification 정의
6. Jenkins Pipeline 내에서 Build Gradle 정의
7. Jenkins Pipeline 내에서 ECR Registry & ECS Deploy 정의
8. Jenkins Pipeline 내에서 커밋 로그 추출 Slack WebWook 정의

🔹 파이프라인을 사용하기 앞서 필요한 Plugin

1️⃣ AWS Credentials Plugin

2️⃣ Pipeline: AWS Steps Plugin

3️⃣ Slack Notification Plugin

4️⃣ Git plugin

🔧 파이프라인 구성 요소 설명

• agent 👉 어디서 실행할지를 정의 (any, label, docker, 등)
• environment 👉 공통 환경변수 설정
• stages 👉 단계들을 그룹핑
• stage 👉 개별 작업 단계 (예: 빌드, 테스트, 배포 등)
• steps 👉 해당 단계에서 수행할 작업들
• post 👉 성공/실패 후의 후처리 작업 정의

🚨 AWS Credentials 정의

1) Jenkins 관리 -> Credentials

2) AWS Credentials 생성

• AWS Access Key Id : 공개적으로 식별 가능한 키
• AWS Secret Access Key : 해당 Access Key ID에 대응하는 비밀번호 같은 비밀 키

※ 젠킨스 파이프라인 ECR Registry & ECS Deploy 해당 Stage 에서 사용 예정

ex) withAWS(credentials: '{AWS Credentials ID}', region: {AWS REGION}

※ 설명하기 앞서서 해당 글에 Stage View는 그림과 같다.

pipeline {
  agent any

  environment {
    BITBUCKET_CREDENTIALS  = 'bc2fa053-e540-48bc-b7f7-b504430a63c9' 		     	 // Bitbucket 자격 증명 ID
    AWS_REGION             = 'ap-northeast-2'                        			    // AWS 리전
    ECR_URI                = '998251115309.dkr.ecr.ap-northeast-2.amazonaws.com'   // ECR URI
    ECR_REPOSITORY_NAME    = 'test'                       						  // ECR 리포지토리 이름
    ECS_CLUSTER_NAME       = 'test-cluster'             						 // ECS 클러스터 이름
    ECS_SERVICE_NAME       = 'test-service'              						// ECS 서비스 이름
    ECR_IMAGE_TAG          = 'latest'                               		   // 이미지 태그
    SLACK_CREDENTIALS      = 'slack'                                		  // Slack 자격 증명 ID
    SLACK_CHANNEL          = '#test-notification'                			 // Slack 채널
    COMMIT_FILE            = "previous_commit_hash.txt"            		    // 커밋 해시 저장 파일
    PREVIOUS_COMMIT        = ''                                    		   // 이전 커밋 해시 (동적 할당용)
    CURRENT_COMMIT         = ''                                     	  // 현재 커밋 해시 (동적 할당용)
  }

  stages {

    stage('Checkout Bitbucket') {
      steps {
        git branch: 'test',
            credentialsId: BITBUCKET_CREDENTIALS,
            url: '{브랜치 주소}'
      }
    }

    stage('Write Dockerfile') {
      steps {
        script {
          // 동적으로 Dockerfile 작성
          writeFile file: 'Dockerfile', text: '''
            FROM amazoncorretto:21
            ARG JAR_FILE=./build/libs/test-0.0.1-SNAPSHOT.jar
            COPY ${JAR_FILE} app.jar
            ENV SPRING_PROFILES_ACTIVE=dev
            ENTRYPOINT ["java", "-Xms3g", "-Xmx3g", "-XX:ActiveProcessorCount=2", "-XX:MaxRAMPercentage=75.0", "-XX:InitialRAMPercentage=75.0", "-jar", "app.jar"]
          '''
        }
      }
    }

    stage('Prepare Slack Notification') {
      steps {
        script {
          // 이전 커밋 해시 확인 (파일에서 읽거나 git에서 가져옴)
          if (fileExists(COMMIT_FILE)) {
            PREVIOUS_COMMIT = readFile(COMMIT_FILE).trim()
          } else {
            PREVIOUS_COMMIT = sh(
              script: "git rev-parse HEAD~1",
              returnStdout: true
            ).trim()
          }

          // 현재 커밋 해시 가져오기
          CURRENT_COMMIT = sh(
            script: "git rev-parse HEAD",
            returnStdout: true
          ).trim()
        }
      }
    }

    stage('Slack Build Notification') {
      steps {
        script {
          // 빌드 시작 알림
          slackSend(
            color: "#439FE0",
            channel: SLACK_CHANNEL,
            message: "*프로젝트 이름 : ${env.JOB_NAME}*\n*빌드번호 : ${env.BUILD_NUMBER}*\n*빌드실행 :jenkins_pepe_1:*",
            tokenCredentialId: SLACK_CREDENTIALS
          )
        }
      }
    }

    stage('Build Gradle') {
      steps {
        // Gradle 빌드 실행
        sh 'chmod +x ./gradlew'
        sh './gradlew clean build -Dorg.gradle.java.home=/usr/lib/jvm/jdk-21'
      }
    }

    stage('ECR Registry & ECS Deploy') {
      steps {
        // AWS 인증 및 배포 작업
        withAWS(credentials: 'aws-credentials-id', region: AWS_REGION) {
          sh '''
            aws ecr get-login-password --region ${AWS_REGION} | docker login --username AWS --password-stdin ${ECR_URI}

            docker build -t ${ECR_REPOSITORY_NAME} .
            docker tag ${ECR_REPOSITORY_NAME}:${ECR_IMAGE_TAG} ${ECR_URI}/${ECR_REPOSITORY_NAME}:${ECR_IMAGE_TAG}
            docker push ${ECR_URI}/${ECR_REPOSITORY_NAME}:${ECR_IMAGE_TAG}

            docker rmi ${ECR_URI}/${ECR_REPOSITORY_NAME}:${ECR_IMAGE_TAG}
            docker rmi ${ECR_REPOSITORY_NAME}:${ECR_IMAGE_TAG}

            aws ecs update-service --cluster ${ECS_CLUSTER_NAME} --service ${ECS_SERVICE_NAME} --force-new-deployment
          '''
        }
      }
    }
  }

  post {
    success {
      script {
        // 변경된 커밋 로그 추출
        def newCommits = sh(
          script: "git log ${PREVIOUS_COMMIT}..${CURRENT_COMMIT} --pretty=format:'%s [%an]'",
          returnStdout: true
        ).trim()

        // 최신 커밋 해시 저장
        writeFile file: COMMIT_FILE, text: CURRENT_COMMIT

        // Slack 알림 - 빌드 성공
        def message = newCommits ?
          newCommits.split('\n').collect { it + "  :jenkins_pepe_2:" }.join('\n') :
          "*반영된 커밋 없음*"

        slackSend(
          color: "#36a64f",
          channel: SLACK_CHANNEL,
          message: "*빌드성공 : ${env.JOB_NAME}*\n*빌드번호 : ${env.BUILD_NUMBER}*\n*반영된 커밋 목록*\n${message}",
          tokenCredentialId: SLACK_CREDENTIALS
        )
      }
    }

    aborted {
      slackSend(
        color: "#ffcc00",
        channel: SLACK_CHANNEL,
        message: "*Build Aborted: ${env.JOB_NAME} - ${env.BUILD_NUMBER}*",
        tokenCredentialId: SLACK_CREDENTIALS
      )
    }

    unstable {
      slackSend(
        color: "#ffcc00",
        channel: SLACK_CHANNEL,
        message: "*Build Unstable: ${env.JOB_NAME} - ${env.BUILD_NUMBER}*",
        tokenCredentialId: SLACK_CREDENTIALS
      )
    }

    failure {
      script {
        // 실패한 빌드의 커밋 로그 추출
        def newCommits = sh(
          script: "git log ${PREVIOUS_COMMIT}..${CURRENT_COMMIT} --pretty=format:'%s [%an]'",
          returnStdout: true
        ).trim()

        // 커밋 해시 저장
        writeFile file: COMMIT_FILE, text: CURRENT_COMMIT

        // Slack 알림 - 빌드 실패
        def message = newCommits ?
          newCommits.split('\n').collect { it + "  :pepe2:" }.join('\n') :
          "*반영된 커밋 없음*"

        slackSend(
          color: "#ff0000",
          channel: SLACK_CHANNEL,
          message: "*빌드실패 : ${env.JOB_NAME}*\n*빌드번호 : ${env.BUILD_NUMBER}*\n*반영된 커밋 목록*\n${message}",
          tokenCredentialId: SLACK_CREDENTIALS
        )
      }
    }
  }
}