[QueryDSL] 설정하기

Gradle에 라이브러리 추가

buildscript {
	ext {
		queryDslVersion = "5.0.0"
	}
}


plugins {
	id 'org.springframework.boot' version '2.6.7'
	id 'io.spring.dependency-management' version '1.0.11.RELEASE'
	id "com.ewerk.gradle.plugins.querydsl" version "1.0.10"	//querydsl 추가
	id 'java'
}

group = 'study'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-web'

	implementation "com.querydsl:querydsl-jpa:${queryDslVersion}"
	implementation "com.querydsl:querydsl-apt:${queryDslVersion}"

	implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.5.8'

	compileOnly 'org.projectlombok:lombok'
	runtimeOnly 'com.h2database:h2'
	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

tasks.named('test') {
	useJUnitPlatform()
}

//querydsl 추가 시작
def querydslDir = "$buildDir/generated/querydsl"

querydsl {
	jpa = true
	querydslSourcesDir = querydslDir
}
sourceSets {
	main.java.srcDir querydslDir
}
compileQuerydsl{
	options.annotationProcessorPath = configurations.querydsl
}
configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
	querydsl.extendsFrom compileClasspath
}
//querydsl 추가 끝

확인하기

QueryDSL 라이브러리가 제대로 설치 됐는지 확인하기 위해서 Test 엔티티 하나를 추가합니다.

@Entity
@Getter
@Setter
public class TmpEntity {
    @Id
    @GeneratedValue
    private Long id;
}

엔티티를 생성한 후, IntelliJ 기준 우측 상단에 있는 Gradle 탭을 누르면 해당 메뉴가 뜹니다. 해당 메뉴에서 'compileQuerydsl' 을 실행합니다.
실행하면, build.gradle 에서 설정한 경로('def querydslDir = "$buildDir/generated/querydsl"')에 파일이 생성됩니다.

사진처럼 Q+엔티티 이름의 클래스가 생성되면 정상적으로 QueryDSL이 설치가 완료된 것입니다.