Uniswap-V2-Core 코드 공부 내용 정리

장원령·2021년 8월 12일
0

Solidity

목록 보기
2/4

1. 개요

: Uniswap은 Defi의 가장 유명한 탈중앙화 거래소이다.
: 트레이더들이 지갑에서 바로 직접 ERC-20토큰들을 거래하거나 스왑할 수 있도록 설계된 탈중앙화 거래소 이다.
: Uniswap의 Contract는 크게 Core(Factory, Pairs), Periphery(Library, Router)로 구성되어 있다.
: 아래의 사이트에서 Uniswap에 대하여 보다 자세한 설명을 해주니 참조하고, 위의 동영상 내용을 간단히 요약해보도록 하자.

https://www.youtube.com/watch?v=CU7ZKnDqhUA&list=PLoiVbVM2-fKBuQdl5J3aR1-GTRVJKQt7l&index=1

uniswap의 작동 원리

: 기존의 방식으로 호가를 올려서 거래할 경우 수수료 등 여러가지 문제가 발생함.
: uniswap은 AMM(Automativ Market Maker) 중에서도 CPMM을 도입했다. 유동성 공급이 공식을 따르게 하는 것(교환 비율을 정해지게 하는 것)

  • CPMM이란?
    : 토큰A 의 수량이 X 토큰 B의 수량이 Y라고 했을때, 이 두 수의 곱이 K를 유지하도록 하는 공식을 사용하는 것이다.
    : uniswap은 이에 항상 pair를 만들어서 관리하게 된다. 이렇기 때문에 많은 pool이 있어야 하기 때문에 contract 주소에 있어서는 효율적이지 않다.

LP token

: reserve를 제공하고 Lp token을 받는다.
: 자기가 공급한 유동성 만큼 , 거래가 많이 일어날수록 수익을 가짐

Defi란?

: 탈중앙화 금융(Decentralized Finance)의 약자로서, 탈중앙화된 분산금융 또는 분산재정을 의미한다. 주로 암호화폐를 담보로 걸고 일정 금액을 대출 받거나, 혹은 다른 담보를 제공하고 암호화폐를 대출 받는 방식으로 작동한다.

2. uniswap-v2-core 코드 분석

: 코어 컨트랙트는 근본적인 Uniswap과 상호작용하는 근본적인 안전 보장을 제공한다.
: 코어는 싱글톤 factory 하나와 많은 pairs로 구성된다.

2.1 ERC20

: ERC20 토큰은 아래와 같다.

pragma solidity =0.5.16;

import './interfaces/IUniswapV2ERC20.sol';
import './libraries/SafeMath.sol';
// 스마트 컨트랙트 실행시 언더플로우 오버플로우 예방을 위함

contract UniswapV2ERC20 is IUniswapV2ERC20 {
    using SafeMath for uint;
    // unit 자료형의 오버플로우를 방지한다. 
    
    string public constant name = 'Uniswap V2';
    string public constant symbol = 'UNI-V2';
    uint8 public constant decimals = 18;
    // 대부분 18을 사용함
    uint  public totalSupply;
    mapping(address => uint) public balanceOf;
    // 주소와 잔액을 연결하는 연관배열 
    mapping(address => mapping(address => uint)) public allowance;

    bytes32 public DOMAIN_SEPARATOR;
    // keccak256("Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)");
    bytes32 public constant PERMIT_TYPEHASH = 0x6e71edae12b1b97f4d1f60370fef10105fa2faae0126114a169c64845d6126c9;
    mapping(address => uint) public nonces;

    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    constructor() public {
        uint chainId;
        // 이더리움 네트워크 체인이 여러가지가 있어 번호를 붙인 것을 의미 
        // 실제 상업적으로 사용되노 있는 메인넷의 chainId가 1번 테스트넷으로 자주 쓰이는 covan ropsten 같은 것의 chain id 가 3번 42번이다. 
        assembly {
            chainId := chainid
        }
        // 어셈블리를 이용하여 가스 비용을 절약하고 :=연산자로 초기화 시킨다. 
        DOMAIN_SEPARATOR = keccak256(
            abi.encode(
                keccak256('EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)'),
                keccak256(bytes(name)),
                keccak256(bytes('1')),
                chainId,
                address(this)
            )
        );
    }
    // internal 제어 접근자를 지닌 경우 상속이 가능하다. 
    function _mint(address to, uint value) internal { // 받을 주소와 받을 토큰의 양 
        totalSupply = totalSupply.add(value); // 총 공급량에 추가 공급량 더함
        balanceOf[to] = balanceOf[to].add(value);  // 모든 잔액을 가진 배열이 balanceof 인데 받을 주소에 추가 공급량을 추가함 
        emit Transfer(address(0), to, value);
    } // 발행 함수 

    function _burn(address from, uint value) internal { // 소각하는 주소와 소각하는 토큰의 양 
        balanceOf[from] = balanceOf[from].sub(value);
        totalSupply = totalSupply.sub(value);
        emit Transfer(from, address(0), value);
    }// 소각 함수 

    function _approve(address owner, address spender, uint value) private {
        allowance[owner][spender] = value;
        emit Approval(owner, spender, value);
    }

    function _transfer(address from, address to, uint value) private {
        balanceOf[from] = balanceOf[from].sub(value);
        balanceOf[to] = balanceOf[to].add(value);
        // from에서 빼서 to로 전송한다. 
        emit Transfer(from, to, value);
    }
    // private접근 제어자를 지닌 approve, transfer의 경우 private으로 호출되고 상속이 불가능하다. 
    function approve(address spender, uint value) external returns (bool) { // spender는 지출 권한이 있는 주소이고 value는 지출할 수 있는 최대 금액이다. 
        _approve(msg.sender, spender, value);
        // msg.sender는 함수를 호출한 사람의 주소이다. 
        return true;
    }

    function transfer(address to, uint value) external returns (bool) {
        _transfer(msg.sender, to, value);
        return true;
    }

    function transferFrom(address from, address to, uint value) external returns (bool) {
        if (allowance[from][msg.sender] != uint(-1)) {
        // uint256(-1)는 uint256의 max 값이다. 
            allowance[from][msg.sender] = allowance[from][msg.sender].sub(value);
        }
        _transfer(from, to, value);
        return true;
    }

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external {
        require(deadline >= block.timestamp, 'UniswapV2: EXPIRED');
        // permit함수의 조건이 require이다. 
        // 'UniswapV2: EXPIRED'는 메인넷에 브로드캐스트 하는데 너무 오래걸리면 나오는 결과라고 한다. 
        // 현재 시간이 데드라인을 초과할 경우 위의 'UniswapV2: EXPIRED'가 출력된다. 
        bytes32 digest = keccak256(
            abi.encodePacked(
            // ncode 방식보다 간편하게 인코딩을 하기위해 abi.encodepacked() 함수를 사용했다고 한다. 
            // 주어진 인수의 압축 인코딩을 수행하는 함수이다. 
                '\x19\x01',
                DOMAIN_SEPARATOR,
                keccak256(abi.encode(PERMIT_TYPEHASH, owner, spender, value, nonces[owner]++, deadline))
            )
        );
        address recoveredAddress = ecrecover(digest, v, r, s);
        // 서명에서 주소를 복구하는 ecrecover 함수를 사용하였다. 
        // 서명값인 v,r,s값과 데이터의 hash값을 ecrecover()에 넣고 실행하면 데이터를 서명한 사용자의 주소가 나오게 된다.
        require(recoveredAddress != address(0) && recoveredAddress == owner, 'UniswapV2: INVALID_SIGNATURE');
        _approve(owner, spender, value);
    }
}
// 접근제어자 external 의 경우 같은 contract 안에서는 부를수없으나, 다른 컨트랙에서는 호출가능

2.2 Factory

: 한 토큰 페어 당 유일한 하나의 컨트랙트를 만드는 역할이다.
: pool을 만드는 컨트랙트이다.
: 먼저 UniswapV2Factory가 상속하는 IUniswapV2Factory 인터페이스에 대하여 알아보겠다. 

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    // pool을 사용하는 사람들이 수수료를 지불하는 주소
    function feeToSetter() external view returns (address);
    // feeTo를 설정할 수 있는 주소

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    // 파라미터로 들어온 두 토큰의 컨트랙트 주소
    function allPairs(uint) external view returns (address pair);
    // 파라미터로 들어온 토큰의 주소 반환 
    function allPairsLength() external view returns (uint);
    // 전체 풀의 개수 

    function createPair(address tokenA, address tokenB) external returns (address pair);
    // 파라미터로 이루어진 Pool을 만든다. 
    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}
pragma solidity =0.5.16;

import './interfaces/IUniswapV2Factory.sol';
import './UniswapV2Pair.sol';

contract UniswapV2Factory is IUniswapV2Factory {
    address public feeTo;
    address public feeToSetter;
    // feeTo를 설정하는 관리자 

    mapping(address => mapping(address => address)) public getPair;
    address[] public allPairs;
    // 모든 pair contract 주소의 모음 

    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    constructor(address _feeToSetter) public {
        feeToSetter = _feeToSetter;
    }

    function allPairsLength() external view returns (uint) {
        return allPairs.length;
    }

    function createPair(address tokenA, address tokenB) external returns (address pair) {
    // 새로운 token pair를 생성하는 함수이다. 
        require(tokenA != tokenB, 'UniswapV2: IDENTICAL_ADDRESSES');
        // 토큰 A, B의 주소가 달라야함. 
        (address token0, address token1) = tokenA < tokenB ? (tokenA, tokenB) : (tokenB, tokenA);
        // tokenA에 작은거 B에 큰거 
        require(token0 != address(0), 'UniswapV2: ZERO_ADDRESS');
        // token0이 ZeroAddress면 실패 
        require(getPair[token0][token1] == address(0), 'UniswapV2: PAIR_EXISTS'); // single check is sufficient
        bytes memory bytecode = type(UniswapV2Pair).creationCode;
        // 바이트 코드(솔리디티로 만든 컨트랙트를 이더리움 네트워크가 인식할 수 있게 번역한 것)를 가져온다. 
        bytes32 salt = keccak256(abi.encodePacked(token0, token1));
        // token 0과 1을 압축, 해시한다. 
        assembly {
            pair := create2(0, add(bytecode, 32), mload(bytecode), salt)
        }
        IUniswapV2Pair(pair).initialize(token0, token1);
        getPair[token0][token1] = pair;
        getPair[token1][token0] = pair; 
        // 양방향 그래프처럼 어느 값 넣어도 나오게 저장 
        allPairs.push(pair);
        // 주소 값을 넣는다. 
        emit PairCreated(token0, token1, pair, allPairs.length);
    }

    function setFeeTo(address _feeTo) external {
        require(msg.sender == feeToSetter, 'UniswapV2: FORBIDDEN');
        feeTo = _feeTo;
    }

    function setFeeToSetter(address _feeToSetter) external {
        require(msg.sender == feeToSetter, 'UniswapV2: FORBIDDEN');
        feeToSetter = _feeToSetter;
    }
}

2.3 Pair

: 먼저 IUniswapV2Pair를 살펴보겠다.

interface IUniswapV2Pair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);
    
    // ERC 20표준 함수 ->
    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);
    // <- ERC 20표준 함수

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;

    event Mint(address indexed sender, uint amount0, uint amount1); // 발행
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}
pragma solidity =0.5.16;

import './interfaces/IUniswapV2Pair.sol';
import './UniswapV2ERC20.sol';
import './libraries/Math.sol';
import './libraries/UQ112x112.sol';
import './interfaces/IERC20.sol';
import './interfaces/IUniswapV2Factory.sol';
import './interfaces/IUniswapV2Callee.sol';

contract UniswapV2Pair is IUniswapV2Pair, UniswapV2ERC20 {
    using SafeMath  for uint;
    using UQ112x112 for uint224;

    uint public constant MINIMUM_LIQUIDITY = 10**3;
    bytes4 private constant SELECTOR = bytes4(keccak256(bytes('transfer(address,uint256)')));

    address public factory;
    address public token0;
    address public token1;

    uint112 private reserve0;           // uses single storage slot, accessible via getReserves
    uint112 private reserve1;           // uses single storage slot, accessible via getReserves
    uint32  private blockTimestampLast; // uses single storage slot, accessible via getReserves

    uint public price0CumulativeLast;
    uint public price1CumulativeLast;
    uint public kLast; // reserve0 * reserve1, as of immediately after the most recent liquidity event

    uint private unlocked = 1;
    modifier lock() {
        require(unlocked == 1, 'UniswapV2: LOCKED');
        unlocked = 0;
        _;
        unlocked = 1;
    }

    function getReserves() public view returns (uint112 _reserve0, uint112 _reserve1, uint32 _blockTimestampLast) {
        _reserve0 = reserve0;
        _reserve1 = reserve1;
        _blockTimestampLast = blockTimestampLast;
    }

    function _safeTransfer(address token, address to, uint value) private {
        (bool success, bytes memory data) = token.call(abi.encodeWithSelector(SELECTOR, to, value));
        require(success && (data.length == 0 || abi.decode(data, (bool))), 'UniswapV2: TRANSFER_FAILED');
    }

    event Mint(address indexed sender, uint amount0, uint amount1);
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    constructor() public {
        factory = msg.sender;
    }

    // called once by the factory at time of deployment
    function initialize(address _token0, address _token1) external {
        require(msg.sender == factory, 'UniswapV2: FORBIDDEN'); // sufficient check
        token0 = _token0;
        token1 = _token1;
    }

    // update reserves and, on the first call per block, price accumulators
    function _update(uint balance0, uint balance1, uint112 _reserve0, uint112 _reserve1) private {
        require(balance0 <= uint112(-1) && balance1 <= uint112(-1), 'UniswapV2: OVERFLOW');
        uint32 blockTimestamp = uint32(block.timestamp % 2**32);
        uint32 timeElapsed = blockTimestamp - blockTimestampLast; // overflow is desired
        if (timeElapsed > 0 && _reserve0 != 0 && _reserve1 != 0) {
            // * never overflows, and + overflow is desired
            price0CumulativeLast += uint(UQ112x112.encode(_reserve1).uqdiv(_reserve0)) * timeElapsed;
            price1CumulativeLast += uint(UQ112x112.encode(_reserve0).uqdiv(_reserve1)) * timeElapsed;
        }
        reserve0 = uint112(balance0);
        reserve1 = uint112(balance1);
        blockTimestampLast = blockTimestamp;
        emit Sync(reserve0, reserve1);
    }

    // if fee is on, mint liquidity equivalent to 1/6th of the growth in sqrt(k)
    function _mintFee(uint112 _reserve0, uint112 _reserve1) private returns (bool feeOn) {
        address feeTo = IUniswapV2Factory(factory).feeTo();
        feeOn = feeTo != address(0);
        uint _kLast = kLast; // gas savings
        if (feeOn) {
            if (_kLast != 0) {
                uint rootK = Math.sqrt(uint(_reserve0).mul(_reserve1));
                uint rootKLast = Math.sqrt(_kLast);
                if (rootK > rootKLast) {
                    uint numerator = totalSupply.mul(rootK.sub(rootKLast));
                    uint denominator = rootK.mul(5).add(rootKLast);
                    uint liquidity = numerator / denominator;
                    if (liquidity > 0) _mint(feeTo, liquidity);
                }
            }
        } else if (_kLast != 0) {
            kLast = 0;
        }
    }
    // feeOn가 참인 경우 fee를 계산하여 새로 토큰을 발행하고, 거짓인 경우는 아무 일도 일어나지 않는다.

    // this low-level function should be called from a contract which performs important safety checks
    function mint(address to) external lock returns (uint liquidity) {
        (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings
        uint balance0 = IERC20(token0).balanceOf(address(this));
        uint balance1 = IERC20(token1).balanceOf(address(this));
        
        uint amount0 = balance0.sub(_reserve0);
        uint amount1 = balance1.sub(_reserve1);
        // 유저가 공급한 두 토큰의 양이다. 

        bool feeOn = _mintFee(_reserve0, _reserve1);
        uint _totalSupply = totalSupply; // gas savings, must be defined here since totalSupply can update in _mintFee
        if (_totalSupply == 0) {
            liquidity = Math.sqrt(amount0.mul(amount1)).sub(MINIMUM_LIQUIDITY);
           _mint(address(0), MINIMUM_LIQUIDITY); // permanently lock the first MINIMUM_LIQUIDITY tokens
        } else {
            liquidity = Math.min(amount0.mul(_totalSupply) / _reserve0, amount1.mul(_totalSupply) / _reserve1);
        }
        require(liquidity > 0, 'UniswapV2: INSUFFICIENT_LIQUIDITY_MINTED');
        _mint(to, liquidity);

        _update(balance0, balance1, _reserve0, _reserve1);
        if (feeOn) kLast = uint(reserve0).mul(reserve1); // reserve0 and reserve1 are up-to-date
        emit Mint(msg.sender, amount0, amount1);
    }

    // this low-level function should be called from a contract which performs important safety checks
    function burn(address to) external lock returns (uint amount0, uint amount1) {
    // lock을 통해 한 사람이 함수를 실행할때 다른이는 실행이 불가능하다. 
        (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings
        address _token0 = token0;                                // gas savings
        address _token1 = token1;                                // gas savings
        uint balance0 = IERC20(_token0).balanceOf(address(this));
        uint balance1 = IERC20(_token1).balanceOf(address(this));
        uint liquidity = balanceOf[address(this)];

        bool feeOn = _mintFee(_reserve0, _reserve1);
        uint _totalSupply = totalSupply; // gas savings, must be defined here since totalSupply can update in _mintFee
        amount0 = liquidity.mul(balance0) / _totalSupply; // using balances ensures pro-rata distribution
        amount1 = liquidity.mul(balance1) / _totalSupply; // using balances ensures pro-rata distribution
        require(amount0 > 0 && amount1 > 0, 'UniswapV2: INSUFFICIENT_LIQUIDITY_BURNED');
        _burn(address(this), liquidity);
        _safeTransfer(_token0, to, amount0);
        _safeTransfer(_token1, to, amount1);
        balance0 = IERC20(_token0).balanceOf(address(this));
        balance1 = IERC20(_token1).balanceOf(address(this));

        _update(balance0, balance1, _reserve0, _reserve1);
        if (feeOn) kLast = uint(reserve0).mul(reserve1); // reserve0 and reserve1 are up-to-date
        emit Burn(msg.sender, amount0, amount1, to);
    }

    // this low-level function should be called from a contract which performs important safety checks
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external lock {
    // calldata는 플래시론(하나의 트랜잭션에서 대출과 상환이 모두 이루어지는 작업)의 경우에만 존재하고 그 외의는 length가 0인 데이터가 들어온다고 한다. 
        require(amount0Out > 0 || amount1Out > 0, 'UniswapV2: INSUFFICIENT_OUTPUT_AMOUNT');
        (uint112 _reserve0, uint112 _reserve1,) = getReserves(); // gas savings
        require(amount0Out < _reserve0 && amount1Out < _reserve1, 'UniswapV2: INSUFFICIENT_LIQUIDITY');

        uint balance0;
        uint balance1;
        { // scope for _token{0,1}, avoids stack too deep errors
        address _token0 = token0;
        address _token1 = token1;
        require(to != _token0 && to != _token1, 'UniswapV2: INVALID_TO');
        // 둘의 주소가 같지 않아야함
        if (amount0Out > 0) _safeTransfer(_token0, to, amount0Out); // optimistically transfer tokens
        if (amount1Out > 0) _safeTransfer(_token1, to, amount1Out); // optimistically transfer tokens
        // 각 양이 0 보다 크면 전송 
        if (data.length > 0) IUniswapV2Callee(to).uniswapV2Call(msg.sender, amount0Out, amount1Out, data);
        balance0 = IERC20(_token0).balanceOf(address(this));
        balance1 = IERC20(_token1).balanceOf(address(this));
        }
        uint amount0In = balance0 > _reserve0 - amount0Out ? balance0 - (_reserve0 - amount0Out) : 0;
        uint amount1In = balance1 > _reserve1 - amount1Out ? balance1 - (_reserve1 - amount1Out) : 0;
        // 잔고 값 체크 
        
        require(amount0In > 0 || amount1In > 0, 'UniswapV2: INSUFFICIENT_INPUT_AMOUNT');
        // 하나가 0 이상인지 체크 
        { // scope for reserve{0,1}Adjusted, avoids stack too deep errors
        
        
        uint balance0Adjusted = balance0.mul(1000).sub(amount0In.mul(3));
        uint balance1Adjusted = balance1.mul(1000).sub(amount1In.mul(3));
        // ? 
        require(balance0Adjusted.mul(balance1Adjusted) >= uint(_reserve0).mul(_reserve1).mul(1000**2), 'UniswapV2: K');
        }

        _update(balance0, balance1, _reserve0, _reserve1);
        emit Swap(msg.sender, amount0In, amount1In, amount0Out, amount1Out, to);
    }

    // force balances to match reserves
    function skim(address to) external lock {
        address _token0 = token0; // gas savings
        address _token1 = token1; // gas savings
        _safeTransfer(_token0, to, IERC20(_token0).balanceOf(address(this)).sub(reserve0));
        _safeTransfer(_token1, to, IERC20(_token1).balanceOf(address(this)).sub(reserve1));
    }

    // force reserves to match balances
    function sync() external lock {
        _update(IERC20(token0).balanceOf(address(this)), IERC20(token1).balanceOf(address(this)), reserve0, reserve1);
    }
}

참조하여 공부한 사이트

profile
장원령
이전 포스트

Solidity-by-example 정리(작성중)

다음 포스트

Uniswap-V2-Periphery 코드 공부 내용 정리

0개의 댓글